FindFFTW.cmake

Go to the documentation of this file.

# Copyright (c) 2025 Niclas Schroeter
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
# This find module defines the following targets and variables:
# - Adds fftw and fftw_single as target
# - Sets FFTW3{f}_INCLUDE_DIRS
# - Sets FFTW3{f}_LIBRARY_DIRS
 
set(FFTW_FOUND_BY_PKGCONF 0)
 
# FFTW3 has a known issue with its autotools-based build.
# See https://github.com/FFTW/fftw3/issues/332
# Essentially the CMake files are not built properly.
message(WARNING "HPCW does not check for FFTW3Config.cmake by default \
due to a bug in FFTW3. If you want to use these files to discover FFTW3 \
regardless, set FFTW_CMAKE_CONFIG_MODE=ON")
 
if(FFTW_CMAKE_CONFIG_MODE)
  find_package(FFTW3 CONFIG)
  find_package(FFTW3f CONFIG)
endif()
 
if(FFTW3_FOUND AND FFTW3f_FOUND)
  add_library(fftw UNKNOWN IMPORTED)
  add_library(fftw_single UNKNOWN IMPORTED)
else()
  find_package(PkgConfig)
  if(PKG_CONFIG_FOUND)
    pkg_check_modules(FFTW3 fftw3 IMPORTED_TARGET GLOBAL)
    pkg_check_modules(FFTW3f fftw3f IMPORTED_TARGET GLOBAL)
    if(FFTW3_FOUND AND FFTW3f_FOUND)
      set(FFTW_FOUND_BY_PKGCONF 1)
      add_library(fftw ALIAS PkgConfig::FFTW3)
      add_library(fftw_single ALIAS PkgConfig::FFTW3f)
    endif()
  endif()
endif()
 
if(NOT (FFTW3_FOUND AND FFTW3f_FOUND))
  message(STATUS "Manually looking for fftw")
 
  find_library(FFTW3_LIB fftw3 REQUIRED)
  find_library(FFTW3f_LIB fftw3f REQUIRED)
  find_path(FFTW3_INCLUDE_DIRS NAMES "fftw3.h" REQUIRED)
 
  cmake_path(GET FFTW3_LIB PARENT_PATH FFTW3_LIBRARY_DIRS)
  cmake_path(GET FFTW3f_LIB PARENT_PATH FFTW3f_LIBRARY_DIRS)
  set(FFTW3f_INCLUDE_DIRS "${FFTW3_INCLUDE_DIRS}")
  add_library(fftw UNKNOWN IMPORTED)
  add_library(fftw_single UNKNOWN IMPORTED)
 
  message(STATUS "Found fftw")
endif()
 
# Specifically for ectrans/ecbuild:
# ecbuild doesn't look for fftw3Config.cmake at all. If pkgconf
# fails, they opt to search for the individual parts manually.
# FFTW_ROOT serves as a hint for this case.
if(NOT (FFTW_FOUND_BY_PKGCONF AND FFTW_ROOT))
  cmake_path(GET FFTW3_LIBRARY_DIRS PARENT_PATH FFTW_ROOT)
endif()