eccodes.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2024 David Guibert
# Copyright (c) 2024 - 2025 Niclas Schroeter
# Copyright (c) 2024 Antoine Morvan
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set_property(GLOBAL PROPERTY eccodes_can_use_system TRUE)
set_property(GLOBAL PROPERTY eccodes_depends netcdf libaec ecbuild)
 
set(eccodes_cmake_args "" CACHE STRING "Custom CMake arguments for ecCodes")
set(eccodes_build_args "" CACHE STRING "Custom Make arguments for ecCodes")
 
if(eccodes_enabled)
  if(USE_SYSTEM_eccodes)
    message(STATUS "ECCODES: enabled (system installed)")
    find_package(eccodes MODULE REQUIRED)
 
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}" "${eccodes_LIBRARY_DIRS}")
    set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${eccodes_LIBRARY_DIRS}")
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}" "${eccodes_f90_LIBRARY_DIRS}")
    set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${eccodes_f90_LIBRARY_DIRS}")
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${eccodes_INCLUDE_DIRS}")
  else()
    if(NOT TARGET eccodes)
      message(STATUS "ECCODES: enabled (internally built)")
 
      ExternalProject_Data_Add(
        eccodes
        ${eccodes_revision}
        DEPENDS netcdf::C libaec
        CMAKE_ARGS ${cmake_params}
                   -DBUILD_SHARED_LIBS:BOOL=ON
                   -DCMAKE_INSTALL_PREFIX:FILEPATH=<INSTALL_DIR>
                   -DENABLE_FORTRAN=ON
                   -DECBUILD_TRUST_FLAGS:BOOL=ON
                   -DENABLE_AEC=ON
                   -DENABLE_PNG=OFF
                   -DENABLE_NETCDF=ON
                   -DENABLE_ECCODES_THREADS=ON
                   -DCMAKE_MODULE_PATH=${ecbuild_DIR}/cmake
                   ${default_cmake_args}
                   ${eccodes_cmake_args}
        BUILD_COMMAND ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${eccodes_build_args})
 
      add_library(eccodes_f90 UNKNOWN IMPORTED)
      ExternalProject_Get_Property(eccodes INSTALL_DIR)
      set(ECCODES_DIR ${INSTALL_DIR})
 
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${ECCODES_DIR}/include")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}" "${ECCODES_DIR}/lib64")
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${ECCODES_DIR}/lib64")
      set_if_not_present(ENV{PATH} "$ENV{PATH}" "${ECCODES_DIR}/bin")
    endif()
  endif()
endif()