ecrad.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2025 David Guibert
# Copyright (c) 2024 - 2025 Niclas Schroeter
# Copyright (c) 2024 - 2025 Antoine Morvan
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
include(ExternalData)
 
set_property(GLOBAL PROPERTY ecrad_can_use_system TRUE)
set_property(GLOBAL PROPERTY ecrad_depends netcdf cdo)
 
set(ecrad_build_args "" CACHE STRING "Custom Make arguments for ecRad")
 
option(ecrad_custom_profile "Use a custom Make profile" OFF)
set(ecrad_opt_flags "" CACHE STRING "Optimization flags for custom profile")
set(ecrad_ld_flags "" CACHE STRING "Linker flags for custom profile")
set(ecrad_basic_flags "" CACHE STRING "Basic flags for custom profile")
 
set(test_cases small medium big)
list(TRANSFORM test_cases PREPEND "<BINARY_DIR>/" OUTPUT_VARIABLE required_dirs)
 
if(ecrad_enabled)
  if(USE_SYSTEM_ecrad)
    message(STATUS "ecrad: enabled (system installed)")
    find_program(ECRAD_EXE ecrad REQUIRED)
 
    get_filename_component(ECRAD_EXE_DIR "${ECRAD_EXE}" DIRECTORY)
    set_if_not_present(ENV{PATH} "$ENV{PATH}" "${ECRAD_EXE_DIR}")
 
    # dummy ecrad external project to get tests
    ExternalProject_Data_Add(
      ecrad
      ${ecrad_revision}
      CONFIGURE_COMMAND ""
      BUILD_COMMAND ""
      INSTALL_COMMAND ${CMAKE_COMMAND} -E make_directory ${required_dirs})
 
    ExternalProject_Get_Property(ecrad BINARY_DIR)
    set(ecrad_BIN_DIR ${BINARY_DIR})
 
  else()
    message(STATUS "ecrad: enabled (internally built)")
 
    set(omp_simd_unsupported False)
    if(CMAKE_Fortran_COMPILER_ID MATCHES "^LLVMFlang$")
      message(STATUS "Enabling custom profile for LLVM")
      set(ecrad_custom_profile True)
      set(ecrad_opt_flags "-O3 -march=native -ffp-contract=fast -ffast-math ${ecrad_opt_flags}")
 
      # In LLVM versions <= 20, OpenMP is still experimental and !$omp simd reducions are not implemented
      if(CMAKE_Fortran_COMPILER_VERSION VERSION_LESS 21)
        set(omp_simd_unsupported True)
      endif()
    endif()
 
 
    # Check compiler to set the PROFILE argument of make command
    set(copy_cmd "true")
    if(ecrad_custom_profile)
      set(ECRAD_COMPILER_PROFILE "custom")
      message(STATUS "Building a custom Make profile...")
      find_package(OpenMP REQUIRED)
      set(custom_profile_path "${CMAKE_CURRENT_BINARY_DIR}/Makefile_include.custom")
      set(copy_cmd "cp ${custom_profile_path} <SOURCE_DIR>")
 
      file(GENERATE OUTPUT ${custom_profile_path} CONTENT "
FC = ${CMAKE_Fortran_COMPILER}
CC = ${CMAKE_C_COMPILER}
OPTFLAGS = ${ecrad_opt_flags}
LDFLAGS = ${ecrad_ld_flags}
BASICFLAGS = ${CMAKE_Fortran_MODDIR_FLAG}../mod ${ecrad_basic_flags}
OMPFLAG = ${OpenMP_Fortran_FLAGS}"
    )
    elseif(CMAKE_Fortran_COMPILER_ID STREQUAL "GNU")
      set(ECRAD_COMPILER_PROFILE "gfortran")
    elseif(CMAKE_Fortran_COMPILER_ID MATCHES "^Intel(LLVM)?$")
      set(ECRAD_COMPILER_PROFILE "intel")
    else()
      message(
        FATAL_ERROR
          "ecrad: compiler profile not supported (${CMAKE_Fortran_COMPILER_ID}). Provide a custom profile instead!"
      )
    endif()
 
 
    ExternalProject_Data_Add(
      ecrad
      DEPENDS netcdf::Fortran ${ecrad_revision}
 
      # Remove some omp directive that's supposed to be supported by an undocumented compiler.
      # see https://github.com/ecmwf-ifs/ecrad/pull/50
      PATCH_COMMAND ${Patch_EXECUTABLE} -p1 -i ${CMAKE_SOURCE_DIR}/projects/ecrad_omp_simd_declare.patch
      # Remove some omp simd reduction when they are not supported
      COMMAND       $<IF:$<NOT:$<BOOL:${omp_simd_unsupported}>>,true,${Patch_EXECUTABLE} -p1 -i ${CMAKE_SOURCE_DIR}/projects/ecrad_omp_simd_reduction.patch>
 
      CONFIGURE_COMMAND bash -c ${copy_cmd}
      BUILD_COMMAND env
        PATH=$ENV{PATH} CPATH=$ENV{CPATH}
        C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
        LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        ${CMAKE_MAKE_PROGRAM} -j 1 PROFILE=${ECRAD_COMPILER_PROFILE} FC=${CMAKE_Fortran_COMPILER} ${default_build_args} ${ecrad_build_args}
      INSTALL_COMMAND ${CMAKE_COMMAND} -E make_directory ${required_dirs}
      COMMAND ${CMAKE_COMMAND} -E make_directory <INSTALL_DIR>
      COMMAND ${CMAKE_COMMAND} -E copy_directory <BINARY_DIR>/bin
              <INSTALL_DIR>/bin
      COMMAND ${CMAKE_COMMAND} -E copy_directory <BINARY_DIR>/lib
              <INSTALL_DIR>/lib
    )
 
    ExternalProject_Get_Property(ecrad INSTALL_DIR)
    set(ecrad_DIR ${INSTALL_DIR})
 
    set_if_not_present(ENV{PATH} "$ENV{PATH}" "${ecrad_DIR}/bin")
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                       "${ecrad_DIR}/lib")
 
    ExternalProject_Get_Property(ecrad BINARY_DIR)
    set(ecrad_BIN_DIR ${BINARY_DIR})
    set_if_not_present(ENV{PATH} "$ENV{PATH}" "${ecrad_BIN_DIR}/bin")
  endif()
 
  #The large tests require inputs that are NC4 files. ecRad requires setting a parameter in the radiation_driver namelist to
  #enable reading and writing of this file format. Additionally, the tests are repeated 5 times by adding the other parameter.
  #For comparability's sake, the small test is also executed with this adjusted namelist.
  set(awk_add_params "awk '/do_write_double_precision/ { print; print \"do_write_hdf5 = true,\\nnrepeat = 5,\"; next }1'")
  set(namelist_large_files configLargeFiles.nam)
  set(namelist_creation "${awk_add_params} config.nam > ${namelist_large_files}")
  set(append_new_namelist "&& ${namelist_creation}")
 
  #Setting up the directories' contents
  foreach(case IN LISTS test_cases)
    add_test(
      NAME ecrad-${case}-stage-in
      COMMAND
        env LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        PATH=$ENV{PATH} $<TARGET_FILE:job_launcher> --name=ecrad-${case}-stage-in
        --log-dir=${LOG_DIR}
        --
        bash -c "${ecrad_BIN_DIR}/bin/create_practical.sh ${append_new_namelist}"
      WORKING_DIRECTORY ${ecrad_BIN_DIR}/${case}
    )
  endforeach()
 
  add_test(
    NAME ecrad-small
    COMMAND
      env LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
      PATH=$ENV{PATH} $<TARGET_FILE:job_launcher> --name=ecrad-small
      --log-dir=${LOG_DIR}
      -- ecrad
      ${namelist_large_files} era5slice.nc control.nc
    WORKING_DIRECTORY ${ecrad_BIN_DIR}/small
  )
 
  #The large two tests require input data from outside of ecRad.
  ExternalData_Add_Test(offline_ecrad_medium
    NAME ecrad-medium
    COMMAND
      env LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
      PATH=$ENV{PATH} $<TARGET_FILE:job_launcher> --name=ecrad-medium
      --log-dir=${LOG_DIR}
      -- ecrad
      ${namelist_large_files} DATA{inputs/ecrad/era5sliceConcat1000.nc} control.nc
    WORKING_DIRECTORY ${ecrad_BIN_DIR}/medium
  )
 
  ExternalData_Add_Test(offline_ecrad_big
    NAME ecrad-big
    COMMAND
      env LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
      PATH=$ENV{PATH} $<TARGET_FILE:job_launcher> --name=ecrad-big
      --log-dir=${LOG_DIR}
      -- ecrad
      ${namelist_large_files} DATA{inputs/ecrad/era5sliceConcat2000.nc} control.nc
    WORKING_DIRECTORY ${ecrad_BIN_DIR}/big
  )
 
  ExternalData_Add_Target(offline_ecrad_medium)
  ExternalData_Add_Target(offline_ecrad_big)
  add_dependencies(offline offline_ecrad_medium offline_ecrad_big)
 
  foreach(case IN LISTS test_cases)
    ExternalData_Add_Test(offline_ecrad_${case}_validation
      NAME ecrad-${case}-validation
      COMMAND
        env LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        PATH=$ENV{PATH} $<TARGET_FILE:job_launcher> --name=ecrad-${case}-validation 
        --log-dir=${LOG_DIR}
        --
        cdo diff,abslim=0.001 DATA{inputs/ecrad/ref-${case}.nc} control.nc
      WORKING_DIRECTORY ${ecrad_BIN_DIR}/${case}
    )
    ExternalData_Add_Target(offline_ecrad_${case}_validation)
    add_dependencies(offline offline_ecrad_${case}_validation)
 
    set_tests_properties(ecrad-${case}-stage-in PROPERTIES FIXTURES_SETUP _setup-ecrad-${case})
    set_tests_properties(ecrad-${case} PROPERTIES FIXTURES_SETUP _run-ecrad-${case})
 
    set_tests_properties(ecrad-${case} PROPERTIES FIXTURES_REQUIRED _setup-ecrad-${case})
    set_tests_properties(ecrad-${case}-validation PROPERTIES FIXTURES_REQUIRED _run-ecrad-${case})
  endforeach()
 
endif(ecrad_enabled)