fetchFromEP.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2024 David Guibert
# Copyright (c) 2024 Niclas Schroeter
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
# https://cmake.org/cmake/help/latest/module/ExternalData.html#custom-fetch-scripts
#ExternalData_CUSTOM_LOCATION
#    When a custom fetch script is loaded, this variable is set to the location part of the URL, which will contain the substituted hash algorithm name and content hash value.
#
#ExternalData_CUSTOM_FILE
#    When a custom fetch script is loaded, this variable is set to the full path to a file in which the script must store the fetched content. The name of the file is unspecified and should not be interpreted in any way.
# The custom fetch script is expected to store fetched content in the file or set a variable:
# ExternalData_CUSTOM_ERROR
#     When a custom fetch script fails to fetch the requested content, it must set this variable to a short one-line message describing the reason for failure.
 
cmake_path(GET ExternalData_CUSTOM_SCRIPT_fetchURL PARENT_PATH SOURCE_DIR)
include(${SOURCE_DIR}/../versions.cmake)
 
list(FIND fetchfromep_list ${ExternalData_CUSTOM_LOCATION} hash_pos)
 
math(EXPR next_pos "${hash_pos} + 1")
 
if(next_pos GREATER "0")
  list(GET fetchfromep_list ${next_pos} name)
  list(GET fetchfromep_list ${hash_pos} hash)
  string(REGEX REPLACE "/" "=" hash "${hash}")
  string(REGEX REPLACE ".*${ExternalData_CUSTOM_LOCATION};(.*)(MD5|SHA256)*.*" "\\1" ep_args "${fetchfromep_list}")
  # remove trailing checksums
  string(REGEX REPLACE "(,*);(MD5|SHAR256|$).*" "\\1" ep_args "${ep_args}")
 
  message(STATUS "fetchFromEP: ${ep_args}...")
 
  include(FetchContent)
  FetchContent_Populate(
    ${ep_args}
    SOURCE_DIR ${name}
    )
  # https://www.gnu.org/software/tar/manual/html_node/Reproducibility.html
  execute_process(COMMAND bash -xc "env LC_ALL=C tar --sort=name --format=posix --pax-option=exthdr.name=%d/PaxHeaders/%f --pax-option=delete=atime,delete=ctime --clamp-mtime --mtime='1971-01-01T00:00:00Z' --numeric-owner --owner=0 --group=0 --mode=go+u,go-w --exclude-vcs -cvf - ${name} | gzip --no-name --best > ${ExternalData_CUSTOM_FILE}")
 
  file(MD5 "${ExternalData_CUSTOM_FILE}" md5hash)
  file(SHA256 "${ExternalData_CUSTOM_FILE}" sha256hash)
  string(REGEX REPLACE "^.*=" "" hash "${hash}")
 
  if(NOT (md5hash STREQUAL hash OR sha256hash STREQUAL hash))
    set(ExternalData_CUSTOM_ERROR "Computed hashes ${md5hash} and ${sha256hash}, expected ${hash}")
  endif()
else()
  message(DEBUG "FetchFromEP: unknown hash ${ExternalData_CUSTOM_LOCATION}")
 
  # touch the file to allow other custom scripts (if any)
  cmake_path(GET ExternalData_CUSTOM_FILE PARENT_PATH STORE_DIR)
  file(MAKE_DIRECTORY ${STORE_DIR})
  file(TOUCH ${ExternalData_CUSTOM_FILE})
endif()