fetchURL.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2024 David Guibert
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
# https://cmake.org/cmake/help/latest/module/ExternalData.html#custom-fetch-scripts
#ExternalData_CUSTOM_LOCATION
#    When a custom fetch script is loaded, this variable is set to the location part of the URL, which will contain the substituted hash algorithm name and content hash value.
#
#ExternalData_CUSTOM_FILE
#    When a custom fetch script is loaded, this variable is set to the full path to a file in which the script must store the fetched content. The name of the file is unspecified and should not be interpreted in any way.
# The custom fetch script is expected to store fetched content in the file or set a variable:
# ExternalData_CUSTOM_ERROR
#     When a custom fetch script fails to fetch the requested content, it must set this variable to a short one-line message describing the reason for failure.
 
cmake_path(GET ExternalData_CUSTOM_SCRIPT_fetchURL PARENT_PATH SOURCE_DIR)
include(${SOURCE_DIR}/../versions.cmake)
 
list(FIND fetchurl_list ${ExternalData_CUSTOM_LOCATION} hash_pos)
 
math(EXPR url_pos "${hash_pos} + 1")
 
if(url_pos GREATER "0")
  list(GET fetchurl_list ${url_pos} url)
  list(GET fetchurl_list ${hash_pos} hash)
  string(REGEX REPLACE "/" "=" hash "${hash}")
 
  message(STATUS "fetchURL: ${url}...")
  file(DOWNLOAD ${url} ${ExternalData_CUSTOM_FILE} STATUS status SHOW_PROGRESS TIMEOUT 0 EXPECTED_HASH ${hash})
 
  list(GET status 0 code)
  if(NOT code EQUAL 0)
    list(GET status 1 ExternalData_CUSTOM_ERROR)
  endif()
else()
  message(DEBUG "FetchURL: unknown hash ${ExternalData_CUSTOM_LOCATION}")
 
  # touch the file to allow other custom scripts (if any)
  cmake_path(GET ExternalData_CUSTOM_FILE PARENT_PATH STORE_DIR)
  file(MAKE_DIRECTORY ${STORE_DIR})
  file(TOUCH ${ExternalData_CUSTOM_FILE})
endif()