fftw.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2024 David Guibert
# Copyright (c) 2024 - 2025 Antoine Morvan
# Copyright (c) 2024 - 2025 Niclas Schroeter
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set_property(GLOBAL PROPERTY fftw_can_use_system TRUE)
set_property(GLOBAL PROPERTY fftw_depends mpi)
 
set(fftw_configure_args "" CACHE STRING "Custom configure arguments for FFTW")
set(fftw_build_args "" CACHE STRING "Custom Make arguments for FFTW")
 
if(fftw_enabled)
  if(USE_SYSTEM_fftw)
    message(STATUS "FFTW: enabled (system installed)")
    if(DEFINED ENV{MKLROOT} OR DEFINED ENV{MKL_ROOT})
      find_package(MKL CONFIG REQUIRED PATHS $ENV{MKLROOT} $ENV{MKL_ROOT})
 
      add_library(fftw ALIAS MKL::MKL)
      add_library(fftw_single ALIAS MKL::MKL)
    else()
      find_package(FFTW MODULE REQUIRED)
 
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${FFTW3_LIBRARY_DIRS}")
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${FFTW3f_LIBRARY_DIRS}")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}" "${FFTW3_LIBRARY_DIRS}")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}" "${FFTW3f_LIBRARY_DIRS}")
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${FFTW3_INCLUDE_DIRS}")
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${FFTW3f_INCLUDE_DIRS}")
    endif()
  else()
    message(STATUS "FFTW: enabled (internally built)")
 
    set(myCFLAGS "")
    list(APPEND myCFLAGS -fPIC)
    if(CMAKE_Fortran_COMPILER_ID STREQUAL "Intel")
      list(APPEND myCFLAGS -gcc-sys)
    endif()
    if(CMAKE_Fortran_COMPILER_ID STREQUAL "GNU")
      list(APPEND myCFLAGS -DPIC)
    endif()
    list(JOIN myCFLAGS " " CFLAGS)
 
    set(BUILD_WRAPPER ./configure)
    list(
      APPEND
      BUILD_WRAPPER
      --enable-mpi
      --enable-shared
      --enable-openmp
      --enable-threads)
    EXECUTE_PROCESS( COMMAND uname -m COMMAND tr -d '\n' OUTPUT_VARIABLE ARCHITECTURE )
    if (ARCHITECTURE STREQUAL x86_64)
      list(
        APPEND
        BUILD_WRAPPER
        --enable-fma
        --enable-sse2
        --enable-avx
        --enable-avx2
        --enable-avx512)
    elseif(ARCHITECTURE STREQUAL aarch64)
      list(
        APPEND
        BUILD_WRAPPER
        --enable-neon
        --enable-fma
        --enable-sve
        --enable-armv8-cntvct-el0)
    else()
        message(FATAL_ERROR "Architecture '${ARCHITECTURE}' is not supported by HPCW")
    endif()
 
    # FIXME: enable conditionnally list(APPEND BUILD_WRAPPER --enable-avx512)
    list(APPEND BUILD_WRAPPER "CFLAGS=${CFLAGS}")
 
    # Double precision FFTW
    ExternalProject_Data_Add(
      fftw
      DEPENDS MPI::MPI_C ${fftw_revision}
      CONFIGURE_COMMAND
        # https://github.com/RemiLacroix-IDRIS/spack/commit/d2edb5f3571674c8724360018ca4f1d488a4806a
        sed -i -e "s@-no-gcc@-gcc-sys@" configure
      COMMAND env
        PATH=$ENV{PATH} CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
        LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        CC=${CMAKE_C_COMPILER} CXX=${CMAKE_CXX_COMPILER}
        FC=${CMAKE_Fortran_COMPILER} MPICC=${MPI_C_COMPILER}
        MPICXX=${MPI_CXX_COMPILER} MPIFC=${MPI_Fortran_COMPILER}
        ${BUILD_WRAPPER} --prefix=<INSTALL_DIR> ${default_configure_args} ${fftw_configure_args}
      BUILD_COMMAND env
        PATH=$ENV{PATH} CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
        LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${fftw_build_args})
 
    # Single precision FFTW
    ExternalProject_Data_Add(
      fftw_single
      DEPENDS MPI::MPI_C fftw ${fftw_revision}
      CONFIGURE_COMMAND
        # https://github.com/RemiLacroix-IDRIS/spack/commit/d2edb5f3571674c8724360018ca4f1d488a4806a
        sed -i -e "s@-no-gcc@-gcc-sys@" configure
      COMMAND env
        PATH=$ENV{PATH} CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
        LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        CC=${CMAKE_C_COMPILER} CXX=${CMAKE_CXX_COMPILER}
        FC=${CMAKE_Fortran_COMPILER} MPICC=${MPI_C_COMPILER}
        MPICXX=${MPI_CXX_COMPILER} MPIFC=${MPI_Fortran_COMPILER}
        ${BUILD_WRAPPER} --prefix=<INSTALL_DIR> --enable-single ${default_configure_args} ${fftw_configure_args}
      BUILD_COMMAND env
        PATH=$ENV{PATH} CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
        LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${fftw_build_args})
 
    ExternalProject_Get_Property(fftw INSTALL_DIR)
    set(FFTW_DIR ${INSTALL_DIR})
 
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${FFTW_DIR}/include")
    set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${FFTW_DIR}/lib")
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                       "${FFTW_DIR}/lib")
 
  endif()
endif(fftw_enabled)