hdf5.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2024 David Guibert
# Copyright (c) 2024 - 2025 Antoine Morvan
# Copyright (c) 2024 - 2025 Niclas Schroeter
# Copyright (c) 2024 Daniel Beltran-Mora
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set_property(GLOBAL PROPERTY hdf5_can_use_system TRUE)
set_property(GLOBAL PROPERTY hdf5_depends szip zlib)
set_property(GLOBAL PROPERTY hdf5_depends_optional mpi)
 
 
if(DEFINED hdf5_configure_args)
  message( FATAL_ERROR
    "HDF5 recipe in HPCW has been updated to use CMake instead of configure script."
    "Hence, \${hdf5_cmake_args} is used instead of \${hdf5_configure_args}."
    "We have detected that you are still using \${hdf5_configure_args}, which now triggers this error."
    "Please update your scripts and/or toolchains to update the build flags accordingly and define \${hdf5_cmake_args}.")
endif()
set(hdf5_cmake_args "" CACHE STRING "Custom CMake arguments for HDF5")
set(hdf5_build_args "" CACHE STRING "Custom Make arguments for HDF5")
 
if(hdf5_enabled)
  if(USE_SYSTEM_hdf5)
    message(STATUS "HDF5: enabled (system installed)")
    enable_language(Fortran)
    set(HDF5_FIND_DEBUG ON)
    find_package(
      HDF5
      COMPONENTS C Fortran HL
      REQUIRED)
 
    if(NOT HDF5_C_LIBRARY)
      list(GET HDF5_C_LIBRARIES 0 HDF5_C_LIBRARY)
    endif()
    if(NOT TARGET hdf5::hdf5)
      add_library(hdf5::hdf5 UNKNOWN IMPORTED)
      set_target_properties(
        hdf5::hdf5
        PROPERTIES IMPORTED_LOCATION "${HDF5_C_LIBRARY}"
                   COMPILE_DEFINITIONS "${HDF5_C_DEFINITIONS}"
                   INTERFACE_INCLUDE_DIRECTORIES "${HDF5_C_INCLUDE_DIRS}"
                   LINK_LIBRARIES "${HDF5_C_LIBRARIES};curl" # FIXME missing
                                                             # dependency found
      )
    endif()
 
    if(NOT HDF5_Fortran_LIBRARY)
      list(GET HDF5_Fortran_LIBRARIES 0 HDF5_Fortran_LIBRARY)
    endif()
    if(NOT TARGET hdf5::hdf5_fortran)
      add_library(hdf5::hdf5_fortran UNKNOWN IMPORTED)
      set_target_properties(
        hdf5::hdf5_fortran
        PROPERTIES IMPORTED_LOCATION "${HDF5_Fortran_LIBRARY}"
                   COMPILE_DEFINITIONS "${HDF5_Fortran_DEFINITIONS}"
                   INTERFACE_INCLUDE_DIRECTORIES "${HDF5_Fortran_INCLUDE_DIRS}"
                   LINK_LIBRARIES "${HDF5_Fortran_LIBRARIES}")
    endif()
 
    if(NOT HDF5_C_HL_LIBRARY)
      list(GET HDF5_C_HL_LIBRARIES 0 HDF5_C_HL_LIBRARY)
    endif()
    if(NOT TARGET hdf5::hdf5_hl)
      add_library(hdf5::hdf5_hl UNKNOWN IMPORTED)
      set_target_properties(
        hdf5::hdf5_hl
        PROPERTIES IMPORTED_LOCATION "${HDF5_C_HL_LIBRARY}"
                   LINK_LIBRARIES "${HDF5_C_HL_LIBRARIES};hdf5::hdf5")
    endif()
 
    # HDF5_C_HL_LIBRARIES:
    # /scratch_lustre_DDN7k/bguibertd/s/install-intel18/hdf5/lib/libhdf5_hl.so
    get_filename_component(HDF5_DIR "${HDF5_C_LIBRARY}" DIRECTORY)
    get_filename_component(HDF5_DIR "${HDF5_DIR}" DIRECTORY)
    message(STATUS "-> HDF5_DIR: ${HDF5_DIR}")
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${HDF5_DIR}/include")
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${HDF5_DIR}/include/shared")
    set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${HDF5_DIR}/lib")
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                       "${HDF5_DIR}/lib")
    set_if_not_present(ENV{PATH} "$ENV{PATH}" "${HDF5_DIR}/bin")
 
  else()
 
    if(NOT TARGET hdf5)
      message(STATUS "HDF5: enabled (internally built)")
      if(mpi_enabled)
        set(hdf5_depends_ep MPI::MPI_C MPI::MPI_Fortran)
      endif()
      if(NOT USE_SYSTEM_zlib)
        set(hdf5_depends_ep zlib)
      endif()
 
      ExternalProject_Data_Add(
        hdf5
        ${hdf5_revision}
        DEPENDS szip ${hdf5_depends_ep}
 
        # See https://github.com/ecmwf-ifs/ecrad/issues/16
        # See https://github.com/HDFGroup/hdf5/issues/3831
        # Patch comes from here https://github.com/HDFGroup/hdf5/commit/e0d095ebf020706ec7d7c82e6674b18f1a0a2d5b
        # But removed the RELEASE.txt changes
        PATCH_COMMAND ${Patch_EXECUTABLE} -p1 -i
                ${CMAKE_SOURCE_DIR}/projects/hdf5_sigfpe.patch
 
        CMAKE_ARGS ${cmake_params}
          -DCMAKE_INSTALL_LIBDIR:FILEPATH=lib
          -DCMAKE_INSTALL_PREFIX:FILEPATH=<INSTALL_DIR>
          -DCMAKE_BUILD_TYPE:STRING=Release
          -DBUILD_SHARED_LIBS:BOOL=ON
          -DBUILD_STATIC_LIBS:BOOL=ON
          -DHDF5_ENABLE_ZLIB_SUPPORT=ON
          -DHDF5_ENABLE_SZIP_SUPPORT=ON
          -DHDF5_BUILD_FORTRAN=ON
          -DHDF5_ENABLE_PARALLEL=${mpi_enabled}
          -DHDF5_BUILD_HL_LIB=ON
          -DBUILD_TESTING=OFF
          -DHDF5_BUILD_EXAMPLES=OFF
          ${default_cmake_args}
          ${hdf5_cmake_args}
        BUILD_COMMAND   ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${hdf5_build_args}
        INSTALL_COMMAND ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} PREFIX=<INSTALL_DIR> install
      )
 
      ExternalProject_Get_Property(hdf5 INSTALL_DIR)
      set(HDF5_DIR ${INSTALL_DIR})
 
      ExternalProject_Get_Property(hdf5 BINARY_DIR)
      set(HDF5_BIN_DIR ${BINARY_DIR})
 
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${HDF5_DIR}/include")
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${HDF5_DIR}/include/shared")
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                         "${HDF5_DIR}/lib")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                         "${HDF5_DIR}/lib")
      set_if_not_present(ENV{PATH} "$ENV{PATH}" "${HDF5_DIR}/bin")
      set_if_not_present(ENV{C_INCLUDE_PATH} "$ENV{C_INCLUDE_PATH}" "${HDF5_DIR}/include")
      set_if_not_present(ENV{CPLUS_INCLUDE_PATH} "$ENV{CPLUS_INCLUDE_PATH}" "${HDF5_DIR}/include")
 
      add_library(hdf5::hdf5 STATIC IMPORTED)
      set_target_properties(
        hdf5::hdf5
        PROPERTIES
      IMPORTED_LOCATION "${INSTALL_DIR}/lib/libhdf5.a"
          INTERFACE_INCLUDE_DIRECTORIES "${INSTALL_DIR}/include"
        IMPORTED_LOCATION "${INSTALL_DIR}/lib/libhdf5.a"
          LINK_LIBRARIES
          "m;dl;${INSTALL_DIR}/lib/libhdf5.a;curl;SZIP::SZIP;ZLIB::ZLIB")
      add_dependencies(hdf5::hdf5 hdf5)
 
      add_library(hdf5::hdf5_hl STATIC IMPORTED)
      set_target_properties(
        hdf5::hdf5_hl
        PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${INSTALL_DIR}/include"
        IMPORTED_LOCATION "${INSTALL_DIR}/lib/libhdf5_hl.a"
                   LINK_LIBRARIES "${INSTALL_DIR}/lib/libhdf5_hl.a;hdf5::hdf5")
      add_dependencies(hdf5::hdf5_hl hdf5)
 
      add_library(hdf5::hdf5_fortran STATIC IMPORTED)
      set_target_properties(
        hdf5::hdf5_fortran
        PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${INSTALL_DIR}/include"
        IMPORTED_LOCATION "${INSTALL_DIR}/lib/libhdf5_fortran.a"
                   LINK_LIBRARIES
                   "${INSTALL_DIR}/lib/libhdf5_fortran.a;hdf5::hdf5")
      add_dependencies(hdf5::hdf5_fortran hdf5)
    endif()
  endif()
 
  # From https://gitlab.kitware.com/cmake/cmake/-/issues/21199 HDF5 1.10.6
  # (released Dec 2019) appears to have changed the naming convention for a
  # Fortran library to be consistent with the other languages. old:
  # hdf5hl_fortran. new: hdf5_hl_fortran.
  if(HDF5_VERSION VERSION_GREATER_EQUAL "1.10.6")
    set(HDF5_HL_Fortran_LIB_NAME "hdf5_hl_fortran")
  else()
    set(HDF5_HL_Fortran_LIB_NAME "hdf5hl_fortran")
  endif()
 
endif()