icon-test-setup.cmake

Go to the documentation of this file.

# Copyright (c) 2019 - 2024 Niclas Schroeter
# Copyright (c) 2019 - 2024 David Guibert
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
include(ExternalData)
 
function(link_icon_tests icon_test directory_creation validation_test)
  set_tests_properties(${directory_creation} PROPERTIES FIXTURES_SETUP _setup-${icon_test})
  set_tests_properties(${icon_test} PROPERTIES FIXTURES_SETUP _run-${icon_test})
 
  set_tests_properties(${validation_test} PROPERTIES FIXTURES_REQUIRED _run-${icon_test})
  set_tests_properties(${icon_test} PROPERTIES FIXTURES_REQUIRED _setup-${icon_test})
endfunction()
 
function(add_icon_test testname input_data_pkg testcase_numbers_list)
  #check input list for number of dirs to create
  set(number_of_testcases 1)
  list(FIND testcase_numbers_list "${testname}" idx)
  if(NOT idx EQUAL -1)
    math(EXPR idx "${idx}+1")
    list(GET testcase_numbers_list ${idx} number_of_testcases)
  endif()
 
  set(copy_flags "-rTn $<$<BOOL:${COPY_ICON_INPUTS}>:-L>")
 
  foreach(i RANGE 1 ${number_of_testcases})
    set(testname_with_suffix "${testname}")
    set(copy_dest "$CACHE{INSTALL_DIR}/inputs/${input_data_pkg}")
    if(NOT ${number_of_testcases} EQUAL 1)
      set(suffix "_${i}")
      string(APPEND testname_with_suffix "${suffix}")
      string(APPEND copy_dest "${suffix}")
    endif()
 
    ExternalData_Add_Test(offline_${testname_with_suffix}
      NAME ${testname_with_suffix}-directory-creation
      COMMAND bash -c "mkdir -p ${copy_dest} && cp ${copy_flags} ${input_data_pkg} ${copy_dest}"
      WORKING_DIRECTORY DATA{inputs/icon/experiments/${input_data_pkg}/,RECURSE:,REGEX:.*}/..
    )
    ExternalData_Add_Target(offline_${testname_with_suffix})
    add_dependencies(offline offline_${testname_with_suffix})
 
    add_test(
      NAME ${testname_with_suffix}
      COMMAND
        env PATH=$ENV{PATH} CPATH=$ENV{CPATH}
        C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
        LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        MPI_C_LIBRARY_VERSION_STRING=${MPI_C_LIBRARY_VERSION_STRING}
        ECCODES_DEFINITION_PATH=${GRIB_DEFINITIONS_DIR}
        $<TARGET_FILE:job_launcher> --name=${testname_with_suffix}
        --log-dir=${LOG_DIR}
        --
        ${ICON_EXE}
      WORKING_DIRECTORY ${copy_dest}
    )
 
    add_test(
      NAME ${testname_with_suffix}-validation
      COMMAND
        env PATH=$ENV{PATH} CPATH=$ENV{CPATH}
        C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
        LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        MPI_C_LIBRARY_VERSION_STRING=${MPI_C_LIBRARY_VERSION_STRING}
        ECCODES_DEFINITION_PATH=${GRIB_DEFINITIONS_DIR}
        $<TARGET_FILE:job_launcher> --name=${testname_with_suffix}-validation
        --log-dir=${LOG_DIR}
        --
        bash validate.sh
      WORKING_DIRECTORY ${copy_dest}
    )
 
    link_icon_tests("${testname_with_suffix}" "${testname_with_suffix}-directory-creation" "${testname_with_suffix}-validation")
  endforeach()
endfunction()
 
function(parse_json_for_test_numbers input_json output_list)
  file(READ ${input_json} content)
  set(index 0)
 
  while(1)
    string(JSON object ERROR_VARIABLE json_error GET ${content} ${index})
    if(NOT json_error STREQUAL NOTFOUND)
      break()
    endif()
 
    string(REGEX MATCH "\"(.+)\"" key_match ${object})
    set(key ${CMAKE_MATCH_1})
 
    string(REGEX MATCHALL "[0-9]+" number_matches ${object})
    list(GET number_matches -1 value)
 
    message(DEBUG "key,value is ${key},${value}")
    list(APPEND ${output_list} ${key} ${value})
    math(EXPR index "${index}+1")
  endwhile()
 
  set(${output_list} "${${output_list}}" PARENT_SCOPE)
endfunction()