icon.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2024 David Guibert
# Copyright (c) 2024 - 2025 Niclas Schroeter
# Copyright (c) 2024 Antoine Morvan
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
include(icon-test-setup)
 
option(ENABLE_icon_gpu "Enable icon gpu parts" OFF)
option(ENABLE_icon_large_inputs "Enable download of large inputs for icon" OFF)
option(COPY_ICON_INPUTS "When creating the test cases, the data is copied instead of linked. Recommended if changes to i.e. namelists are planned." OFF)
set(ICON_TESTCASE_JSON "" CACHE PATH "Absolute path ('~' not expanded) to the input json that contains information on the number of setups per test case.")
set(ICON_USER_BUILD_WRAPPER "" CACHE STRING "Use an existing config wrapper from ICON")
 
set(icon_configure_args "" CACHE STRING "Custom configure arguments for ICON")
set(icon_build_args "" CACHE STRING "Custom Make arguments for ICON")
 
set_property(GLOBAL PROPERTY icon_can_use_system TRUE)
set_property(
  GLOBAL
  PROPERTY icon_depends
           mpi
           openblas
           libxml2
           zlib
           szip
           netcdf
           hdf5
           libfyaml
           cdo
           eccodes)
 
if(ENABLE_icon_gpu)
  set_property(GLOBAL APPEND PROPERTY icon_depends cuda)
endif()
 
if(icon_enabled)
  if (USE_SYSTEM_icon)
    find_program(ICON_EXE icon  REQUIRED)
    message(STATUS "ICON: enabled (system installed)")
    message(STATUS "ICON: ${ICON_EXE}")
    set_if_not_present(ENV{PATH} "$ENV{PATH}" "${ICON_EXE}")
  else ()
    message(STATUS "ICON: enabled (internally built)")
    set(ICON_EXE icon)
 
    set(icon_depends_ep ZLIB::ZLIB SZIP::SZIP netcdf::Fortran libfyaml eccodes eccodes_f90)
    list(APPEND icon_depends_ep openblas LibXml2::LibXml2)
 
    # use configure as default build script, so that specific sites can use
    # specific wrappers that are a lot easier to debug
    set(ICON_BUILD_WRAPPER configure)
 
    # basic libs setup needed for all ICON tests
    set(LIBS_LIST "")
    list(APPEND LIBS_LIST -lxml2)
    list(APPEND LIBS_LIST -lnetcdf)
    list(APPEND LIBS_LIST -lnetcdff)
    list(APPEND LIBS_LIST -lhdf5)
    list(APPEND LIBS_LIST -lhdf5_hl)
    list(APPEND LIBS_LIST -lfyaml)
    list(APPEND LIBS_LIST ${BLAS_LIBRARIES_LIBS})
    list(APPEND LIBS_LIST ${LAPACK_LIBRARIES_LIBS})
    list(APPEND LIBS_LIST ${LAPACK_BLAS_LIBS})
    list(APPEND LIBS_LIST -leccodes)
    list(APPEND LIBS_LIST -leccodes_f90)
    # NVC flags
    set(NVC_FLAGS_LIST "")
 
    if(NOT ICON_USER_BUILD_WRAPPER STREQUAL "")
      set(ICON_BUILD_WRAPPER ${ICON_USER_BUILD_WRAPPER})
    else()
      set(INCLUDE_FLAGS
          "-I${HDF5_DIR}/include -I${NETCDF_DIR}/include -I${NETCDFF_DIR}/include -I${LIBXML2_DIR}/include/libxml2 -I${LIBFYAML_INCLUDE_DIR} -I${ECCODES_DIR}/include"
      )
      list(APPEND ICON_BUILD_WRAPPER "CC=${MPI_C_COMPILER}")
      list(APPEND ICON_BUILD_WRAPPER "CFLAGS=${CFLAGS} $ENV{CFLAGS}")
      list(APPEND ICON_BUILD_WRAPPER "CPPFLAGS=${CPPFLAGS} $ENV{CPPFLAGS} ${INCLUDE_FLAGS}")
      list(APPEND ICON_BUILD_WRAPPER "FC=${MPI_Fortran_COMPILER}")
      list(APPEND ICON_BUILD_WRAPPER "FCFLAGS=${FCFLAGS}  $ENV{FCFLAGS} ${INCLUDE_FLAGS}")
      list(APPEND ICON_BUILD_WRAPPER "ICON_FCFLAGS=${ICON_FCFLAGS}")
 
      set(LDFLAGS_LIST "")
      list(APPEND LDFLAGS_LIST -L${HDF5_DIR}/lib)
      list(APPEND LDFLAGS_LIST -L${NETCDF_DIR}/lib)
      list(APPEND LDFLAGS_LIST -L${NETCDFF_DIR}/lib)
      list(APPEND LDFLAGS_LIST -L${LIBFYAML_LIB_DIR})
      list(APPEND LDFLAGS_LIST -L${LIBXML2_DIR}/lib)
      list(APPEND LDFLAGS_LIST ${BLAS_LINKER_FLAGS})
      list(APPEND LDFLAGS_LIST ${LAPACK_LINKER_FLAGS})
      list(APPEND LDFLAGS_LIST -L${ECCODES_DIR}/lib64)
      if(ENABLE_icon_gpu)
        list(APPEND LDFLAGS_LIST -L${CUDAToolkit_LIBRARY_DIR})
      endif()
      list(JOIN LDFLAGS_LIST " " LDFLAGS_)
      list(APPEND ICON_BUILD_WRAPPER "LDFLAGS=${LDFLAGS} $ENV{LDFLAGS} ${LDFLAGS_}")
 
      if(DEFINED ICON_OCEAN_FCFLAGS OR DEFINED ENV{ICON_OCEAN_FCFLAGS})
        list(APPEND ICON_BUILD_WRAPPER "--enable-fcgroup-OCEAN=src/hamocc:src/ocean:src/sea_ice")
        list(APPEND ICON_BUILD_WRAPPER "ICON_OCEAN_FCFLAGS=${ICON_OCEAN_FCFLAGS}")
      endif()
 
      list(APPEND ICON_BUILD_WRAPPER "MPI_LAUNCH=${MPIEXEC_EXECUTABLE}")
      if(ENABLE_icon_gpu)
        list(APPEND LIBS_LIST -c++libs)
        list(APPEND LIBS_LIST -cuda)
        if(NVCFLAGS) # this is supposed to be a list because of the
                    # space-quotation-black-magic of cmake
          list(JOIN NVCFLAGS " " NVCFLAGS)
          list(APPEND ICON_BUILD_WRAPPER "NVCFLAGS=${NVCFLAGS}")
        endif()
        list(APPEND ICON_BUILD_WRAPPER --enable-gpu)
        # list(APPEND ICON_BUILD_WRAPPER --disable-openmp)             # don't mix
        # gpu and openmp
        list(APPEND ICON_BUILD_WRAPPER --disable-loop-exchange) # don't interfere
                                                                # with manual loop
                                                                # exchange
        list(APPEND ICON_BUILD_WRAPPER --disable-yaxt) # yaxt is not supposed to
                                                      # work on the GPU, yet
      else()
        list(APPEND ICON_BUILD_WRAPPER --disable-gpu --enable-openmp
            --enable-yaxt)
        list(APPEND ICON_BUILD_WRAPPER --enable-intel-consistency
            --enable-vectorized-lrtm)
      endif()
 
      # my workaround for cmake's way to mess around with quotation ALL THE TIME
      list(JOIN LIBS_LIST " " LIBS)
      list(APPEND ICON_BUILD_WRAPPER "LIBS=${LIBS}")
      list(APPEND ICON_BUILD_WRAPPER --enable-parallel-netcdf --enable-mpi
          --disable-mpi-checks)
      list(APPEND ICON_BUILD_WRAPPER --enable-grib2 --enable-ecrad)
      list(APPEND ICON_BUILD_WRAPPER "${default_configure_args};${icon_configure_args}")
    endif()
 
    message("Build ICON with '${ICON_BUILD_WRAPPER}'")
 
    ExternalProject_Data_Add(
      icon
      DEPENDS ${icon_depends_ep}
              ${icon_revision}
      CONFIGURE_COMMAND
      COMMAND env
        CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
        LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        PATH=$ENV{PATH} PARALLEL_LEVEL=${BUILD_PARALLEL_LEVEL}
        <SOURCE_DIR>/${ICON_BUILD_WRAPPER} --prefix=<INSTALL_DIR>
      BUILD_COMMAND env
        PATH=$ENV{PATH} CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
        LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
        ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${icon_build_args}
      INSTALL_COMMAND ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} install)
 
    ExternalProject_Get_Property(icon INSTALL_DIR)
    set(ICON_BIN_DIR "${INSTALL_DIR}/bin")
    set_if_not_present(ENV{PATH} "$ENV{PATH}" "${ICON_BIN_DIR}")
  endif()
 
  #Extra grib definitions for some icon test cases, unpacked in the install
  #directory. Use this variable in ECCODES_DEFINITION_PATH, if required.
  set(GRIB_DEFINITIONS_DIR "${INSTALL_DIR}/share/definitions.edzw")
  ExternalProject_Data_Add(
    eccodes_definitions
    TMP_DIR tmp STAMP_DIR ${name}-stamp
    DOWNLOAD_DIR "${DOWNLOAD_DIR}"
    SOURCE_DIR "${GRIB_DEFINITIONS_DIR}"
    USE_DATA_STORE
    URL DATA{downloads/definitions.edzw.tar.gz}
    CONFIGURE_COMMAND ":"
    BUILD_COMMAND ":"
    INSTALL_COMMAND ":"
  )
 
  set(testcase_numbers_list "")
  if(EXISTS ${ICON_TESTCASE_JSON})
    parse_json_for_test_numbers(${ICON_TESTCASE_JSON} testcase_numbers_list)
  endif()
 
  add_icon_test( "icon-test-nwp-R02B04N06multi" "test_nwp_R02B04N06multi" "${testcase_numbers_list}" )
  add_icon_test( "icon-atm-tracer-Hadley" "atm_tracer_Hadley" "${testcase_numbers_list}" )
  add_icon_test( "icon-aes-physics" "aes_physics" "${testcase_numbers_list}" )
  add_icon_test( "icon-LAM" "LAM" "${testcase_numbers_list}" )
 
  if(ENABLE_icon_large_inputs)
    add_icon_test( "icon-NextGEMS-R2B8-2020" "NextGEMS_R2B8_2020" "${testcase_numbers_list}" )
  endif()
 
endif(icon_enabled)