libxml2.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2024 David Guibert
# Copyright (c) 2024 Antoine Morvan
# Copyright (c) 2024 - 2025 Niclas Schroeter
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set_property(GLOBAL PROPERTY libxml2_can_use_system TRUE)
set_property(GLOBAL PROPERTY libxml2_depends zlib)
 
set(libxml2_configure_args "" CACHE STRING "Custom configure arguments for libxml2")
set(libxml2_build_args "" CACHE STRING "Custom Make arguments for libxml2")
 
if(libxml2_enabled)
  if(USE_SYSTEM_libxml2)
    message(STATUS "LibXml2: enabled (system installed)")
    find_package(LibXml2 REQUIRED)
 
    get_filename_component(LIBXML2_DIR "${LIBXML2_INCLUDE_DIR}" DIRECTORY)
    get_filename_component(LIBXML2_DIR "${LIBXML2_DIR}" DIRECTORY)
    message(STATUS "LIBXML2_DIR: ${LIBXML2_DIR}")
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}"
                       "${LIBXML2_DIR}/include/libxml2")
    set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                       "${LIBXML2_DIR}/lib")
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                       "${LIBXML2_DIR}/lib")
    set_if_not_present(ENV{PATH} "$ENV{PATH}" "${LIBXML2_DIR}/bin")
  else()
    if(NOT TARGET libxml2)
      message(STATUS "libxml2: enabled (internally built)")
 
      find_package(Python REQUIRED)
 
      ExternalProject_Data_Add(
        libxml2
        ${libxml2_revision}
        DEPENDS ZLIB::ZLIB
        CONFIGURE_COMMAND env
          CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
          LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
          CC=${CMAKE_C_COMPILER} CXX=${CMAKE_CXX_COMPILER}
          FC=${CMAKE_Fortran_COMPILER} ./configure --prefix=<INSTALL_DIR>
          --with-python-install-dir=<INSTALL_DIR>/lib/python${Python_VERSION_MAJOR}.${Python_VERSION_MINOR}/site-packages
          --with-zlib=${ZLIB_DIR} ${default_configure_args} ${libxml2_configure_args}
        BUILD_COMMAND env
          CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
          LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
          ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${libxml2_build_args})
 
      ExternalProject_Get_Property(libxml2 INSTALL_DIR)
      set(LIBXML2_DIR ${INSTALL_DIR})
 
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}"
                         "${LIBXML2_DIR}/include/libxml2")
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                         "${LIBXML2_DIR}/lib")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                         "${LIBXML2_DIR}/lib")
      set_if_not_present(
        ENV{PYTHONPATH}
        "$ENV{PYTHONPATH}"
        "${LIBXML2_DIR}/lib/python${Python_VERSION_MAJOR}.${Python_VERSION_MINOR}/site-packages"
      )
 
      add_library(LibXml2::LibXml2 UNKNOWN IMPORTED)
      set_target_properties(
        LibXml2::LibXml2
        PROPERTIES IMPORTED_LOCATION "${LIBXML2_DIR}/lib/libxml2.so"
                   LOCATION "${LIBXML2_DIR}/lib/libxml2.so"
                   INCLUDE_DIRECTORY "${LIBXML2_DIR}/include/libxml2")
 
    endif()
  endif()
endif()