nicamdc.cmake

Go to the documentation of this file.

# Copyright (c) 2024 Sam Hatfield
# Copyright (c) 2024 - 2025 Niclas Schroeter
# Copyright (c) 2024 David Guibert
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set_property(GLOBAL PROPERTY nicamdc_can_use_system TRUE)
set_property(GLOBAL PROPERTY nicamdc_depends mpi)
 
set(nicamdc_change_timestep "10" CACHE STRING "Adjust the number of timesteps for nicamdc test cases (default 10)")
 
set(nicamdc_build_args "" CACHE STRING "Custom Make arguments for nicamdc")
 
if(nicamdc_enabled)
  if(USE_SYSTEM_nicamdc)
    #For externally built versions of Nicam, we are still relying on the
    #presence of the "Makedef." file in the sysdep directory.
    find_program(NICAM_DRIVER nhm_driver REQUIRED)
    get_filename_component(NICAM_ROOT ${NICAM_DRIVER}/../.. ABSOLUTE)
    message(STATUS "nicamdc: enabled (system installed)")
    message(STATUS "nicamdc root: ${NICAM_ROOT}")
    configure_file(${CMAKE_SOURCE_DIR}/cmake/nicamdc-mkjobshell.cmake.in
      ${NICAM_ROOT}/sysdep/Mkjobshell..sh @ONLY)
  else()
    message(STATUS "nicamdc: enabled (internally built)")
 
    if(NOT DEFINED Fortran_ADDITIONAL_FLAGS_FOR_NICAMDC)
      if(CMAKE_Fortran_COMPILER_ID STREQUAL "GNU")
        set(Fortran_ADDITIONAL_FLAGS_FOR_NICAMDC "-fconvert=big-endian -frecord-marker=4")
        # Apart from the record length treatment, GNU also limits the line length to 132 by default.
        string(APPEND Fortran_ADDITIONAL_FLAGS_FOR_NICAMDC " -ffree-line-length-512")
      elseif(CMAKE_Fortran_COMPILER_ID MATCHES "^Intel(LLVM)?$")
        set(Fortran_ADDITIONAL_FLAGS_FOR_NICAMDC "-assume byterecl -convert big_endian")
      else()
        message(FATAL_ERROR "Unrecognized compiler, please define Fortran_ADDITIONAL_FLAGS_FOR_NICAMDC manually")
      endif()
    endif()
 
    # Preprocess makedef template file into a form the NICAM-DC build-system expects
    configure_file(${CMAKE_SOURCE_DIR}/cmake/nicamdc-makedef_file.cmake.in
      ${CMAKE_BINARY_DIR}/Makedef.)
    configure_file(${CMAKE_SOURCE_DIR}/cmake/nicamdc-mkjobshell.cmake.in
      ${CMAKE_BINARY_DIR}/Mkjobshell..sh @ONLY)
 
    # Add NICAM-DC as an external non-CMake project, with custom configure, build, and install
    # commands
    ExternalProject_Data_Add(
      nicamdc
      ${nicamdc_revision}
      CONFIGURE_COMMAND cp ${CMAKE_BINARY_DIR}/Makedef. ${CMAKE_BINARY_DIR}/nicamdc/sysdep/Makedef.
                COMMAND cp ${CMAKE_BINARY_DIR}/Mkjobshell..sh ${CMAKE_BINARY_DIR}/nicamdc/sysdep/Mkjobshell..sh
      PATCH_COMMAND
        ${Patch_EXECUTABLE} -p1 -i ${CMAKE_SOURCE_DIR}/projects/nicam_dependency.patch
      BUILD_COMMAND env NICAM_SYS=
        ${CMAKE_MAKE_PROGRAM} -C ${CMAKE_BINARY_DIR}/nicamdc/src ${default_build_args} ${nicamdc_build_args}
      INSTALL_COMMAND "")
 
    set(NICAM_ROOT "${CMAKE_BINARY_DIR}/nicamdc")
  endif()
 
  # Test cases
  set(cases "small" "medium" "big")
  set(configs "gl05rl00z94pe10" "gl08rl03z94pe640" "gl09rl04z94pe2560")
 
  set(makefile_sed "s/SYSDEPDIR = $(abspath ..)//g")
  set(change_timestep_sed "&& sed -i.orig 's/LSTEP_MAX[[:space:]]*=[[:space:]]*10,/LSTEP_MAX = ${nicamdc_change_timestep},/' nhm_driver.cnf")
 
  # Handle all of the test cases
  foreach(case config IN ZIP_LISTS cases configs)
    # Build the test in a setup step
    add_test(
      NAME build-nicamdc-${case}
      COMMAND
        bash -c "sed -i '${makefile_sed}' Makefile &&
        NICAM_SYS= ${CMAKE_MAKE_PROGRAM} jobshell &&
        ./prepare_rundir.sh ${change_timestep_sed}"
      WORKING_DIRECTORY ${NICAM_ROOT}/test/framework/benchmark/${config})
 
    # Run the test
    add_test(
      NAME nicamdc-${case}
      COMMAND $<TARGET_FILE:job_launcher> --name=nicamdc-${case}
        --log-dir=${LOG_DIR}
        -- ./nhm_driver
      WORKING_DIRECTORY ${NICAM_ROOT}/test/framework/benchmark/${config})
 
    # Make sure build-nicamdc-${case} is always executed before nicamdc-${case}
    set_tests_properties(build-nicamdc-${case} PROPERTIES FIXTURES_SETUP _setup-nicam-${case})
    set_tests_properties(nicamdc-${case} PROPERTIES FIXTURES_REQUIRED _setup-nicam-${case})
 
    #Medium and big test case require extra data in predetermined dirs
    if(NOT case STREQUAL "small")
      set(unpack_data "tar --skip-old-files -xzf nicamdc-${case}.tar.gz")
      set(link_boundary_data "ln -sf $PWD/nicamdc-${case}/boundary/* ${NICAM_ROOT}/data/grid/boundary/")
      set(link_mapping_data "ln -sf $PWD/nicamdc-${case}/llmap/* ${NICAM_ROOT}/data/grid/llmap/")
      set(link_mnginfo_if_present "(test -d $PWD/nicamdc-${case}/mnginfo && ln -sf $PWD/nicamdc-${case}/mnginfo/* ${NICAM_ROOT}/data/mnginfo || true)")
 
      ExternalData_Add_Test(offline_nicamdc_${case}
        NAME link-data-nicamdc-${case}
        COMMAND
          bash -c "${unpack_data} &&
          ${link_boundary_data} &&
          ${link_mapping_data} &&
          ${link_mnginfo_if_present}"
        WORKING_DIRECTORY DATA{inputs/nicamdc/,RECURSE:,REGEX:.*}
      )
      ExternalData_Add_Target(offline_nicamdc_${case})
      add_dependencies(offline offline_nicamdc_${case})
 
      set_tests_properties(link-data-nicamdc-${case} PROPERTIES FIXTURES_SETUP _setup-build-${case})
      set_tests_properties(build-nicamdc-${case} PROPERTIES FIXTURES_REQUIRED _setup-build-${case})
    endif()
 
  endforeach()
endif()