openblas.cmake

Go to the documentation of this file.

# Copyright (c) 2020 - 2024 David Guibert
# Copyright (c) 2024 - 2025 Antoine Morvan
# Copyright (c) 2024 - 2025 Niclas Schroeter
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set(OPENBLAS_BUILD_PARALLEL_LEVEL
    "1"
    CACHE STRING "Enable OpenBLAS parallel compilation")
set_property(GLOBAL PROPERTY openblas_can_use_system TRUE)
set_property(GLOBAL PROPERTY openblas_depends)
 
set(openblas_cmake_args "" CACHE STRING "Custom CMake arguments for OpenBLAS")
set(openblas_build_args "" CACHE STRING "Custom Make arguments for OpenBLAS")
 
if(openblas_enabled)
  if(USE_SYSTEM_blas OR USE_SYSTEM_openblas)
    message(STATUS "blas/lapack: enabled (system installed)")
    # set(BLA_VENDOR Intel10_64lp) set(BLA_F95 ON) #if ON tries to find the
    # BLAS95/LAPACK95 interfaces
 
    find_package(BLAS REQUIRED)
    # BLAS_FOUND library implementing the BLAS interface is found
    # BLAS_LINKER_FLAGS uncached list of required linker flags (excluding -l and
    # -L). BLAS_LIBRARIES uncached list of libraries (using full path name) to
    # link against to use BLAS (may be empty if compiler implicitly links BLAS)
    # BLAS95_LIBRARIES uncached list of libraries (using full path name) to link
    # against to use BLAS95 interface BLAS95_FOUND library implementing the
    # BLAS95 interface is found
 
    # https://cmake.org/cmake/help/latest/module/FindLAPACK.html
    find_package(LAPACK REQUIRED)
    # LAPACK_FOUND library implementing the LAPACK interface is found
    # LAPACK_LINKER_FLAGS uncached list of required linker flags (excluding -l
    # and -L). LAPACK_LIBRARIES uncached list of libraries (using full path
    # name) to link against to use LAPACK LAPACK95_LIBRARIES uncached list of
    # libraries (using full path name) to link against to use LAPACK95
    # LAPACK95_FOUND library implementing the LAPACK95 interface is found
    message(STATUS "BLAS: ${BLAS_FOUND}")
    message(STATUS "LAPACK: ${LAPACK_FOUND}")
 
    add_library(openblas UNKNOWN IMPORTED)
  else()
    if(NOT TARGET openblas)
      message(STATUS "OpenBLAS: enabled (internally built)")
 
      if (CMAKE_Fortran_COMPILER_ID STREQUAL "LLVMFlang")
        set(require_llvm_patch True)
      endif()
 
      ExternalProject_Data_Add(
        openblas
        ${openblas_revision}
 
        PATCH_COMMAND $<IF:$<NOT:$<BOOL:${require_llvm_patch}>>,true,${Patch_EXECUTABLE} -p1 -i ${CMAKE_SOURCE_DIR}/projects/openblas_llvm.patch>
 
        CMAKE_ARGS ${cmake_params}
          -DCMAKE_INSTALL_LIBDIR:FILEPATH=lib
          -DBUILD_SHARED_LIBS:BOOL=${BUILD_SHARED_LIBS}
          -DCMAKE_INSTALL_PREFIX:FILEPATH=<INSTALL_DIR>
          -DCMAKE_BUILD_TYPE:STRING=Release
          -DBUILD_SHARED_LIBS:BOOL=ON
          -DBUILD_STATIC_LIBS:BOOL=ON
          -DUSE_THREAD:BOOL=ON
          -DUSE_OPENMP:BOOL=ON
          -DCMAKE_POLICY_VERSION_MINIMUM=3.5
          ${default_cmake_args}
          ${openblas_cmake_args}
        BUILD_COMMAND   ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${openblas_build_args}
        INSTALL_COMMAND ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} PREFIX=<INSTALL_DIR> install
        )
 
      ExternalProject_Get_Property(openblas INSTALL_DIR)
      set(OPENBLAS_DIR ${INSTALL_DIR})
 
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${OPENBLAS_DIR}/include")
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                         "${OPENBLAS_DIR}/lib")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                         "${OPENBLAS_DIR}/lib")
 
      set(BLAS_FOUND ON)
      set(BLAS_LIBRARIES "${OPENBLAS_DIR}/lib/libopenblas.so")
      set(LAPACK_FOUND ON)
      set(LAPACK_LIBRARIES "${OPENBLAS_DIR}/lib/libopenblas.so")
 
    endif(NOT TARGET openblas)
  endif()
 
  message(STATUS "BLAS_LIBRARIES: ${BLAS_LIBRARIES}")
  message(STATUS "BLAS95_LIBRARIES: ${BLAS95_LIBRARIES}")
  message(STATUS "LAPACK_LIBRARIES: ${LAPACK_LIBRARIES}")
  message(STATUS "LAPACK95_LIBRARIES: ${LAPACK95_LIBRARIES}")
 
  string(REPLACE ";" " " BLAS_LIBRARIES_LIBS "${BLAS_LIBRARIES}")
  string(REPLACE ";" " " BLAS95_LIBRARIES_LIBS "${BLAS95_LIBRARIES}")
  string(REPLACE ";" " " LAPACK_LIBRARIES_LIBS "${LAPACK_LIBRARIES}")
  string(REPLACE ";" " " LAPACK95_LIBRARIES_LIBS "${LAPACK95_LIBRARIES}")
  message(STATUS "BLAS_LIBRARIES_LIBS: ${BLAS_LIBRARIES_LIBS}")
endif(openblas_enabled)