szip.cmake

Go to the documentation of this file.

# Copyright (c) 2019 - 2024 David Guibert
# Copyright (c) 2024 Antoine Morvan
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set_property(GLOBAL PROPERTY szip_can_use_system TRUE)
 
set(szip_configure_args "" CACHE STRING "Custom configure arguments for szip")
set(szip_build_args "" CACHE STRING "Custom Make arguments for szip")
 
if(szip_enabled)
  if(USE_SYSTEM_szip)
    message(STATUS "SZIP: enabled (system installed)")
    set(FIND_SZIP_DEBUG ON)
    find_package(SZIP REQUIRED)
 
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${SZIP_INCLUDE_DIR}")
 
    get_filename_component(SZIP_DIR "${SZIP_LIBRARIES}" PATH)
    get_filename_component(SZIP_DIR "${SZIP_DIR}" PATH)
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${SZIP_DIR}/include")
    set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${SZIP_DIR}/lib")
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                       "${SZIP_DIR}/lib")
  else()
    if(NOT TARGET szip)
      message(STATUS "SZIP: enabled (internally built)")
 
      ExternalProject_Data_Add(
        szip
        ${szip_revision}
        CONFIGURE_COMMAND env
          CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
          LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
          CC=${CMAKE_C_COMPILER} CXX=${CMAKE_CXX_COMPILER}
          FC=${CMAKE_Fortran_COMPILER} ./configure --enable-shared
          --enable-static --enable-production --enable-encoding
          --prefix=<INSTALL_DIR> ${default_configure_args} ${szip_configure_args}
        BUILD_COMMAND env
          CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
          LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
          ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${szip_build_args})
 
      ExternalProject_Get_Property(szip INSTALL_DIR)
      set(SZIP_DIR ${INSTALL_DIR})
 
      set(SZIP_LIBRARIES ${SZIP_DIR}/lib/libsz.so)
      set(SZIP_INCLUDE_DIRS ${SZIP_DIR}/include)
      if(NOT TARGET SZIP::SZIP)
        add_library(SZIP::SZIP UNKNOWN IMPORTED)
        set_target_properties(
          SZIP::SZIP PROPERTIES INTERFACE_INCLUDE_DIRECTORIES
                                ${SZIP_INCLUDE_DIRS})
        if(SZIP_VERSION)
          set_target_properties(SZIP::SZIP PROPERTIES VERSION "${SZIP_VERSION}")
        endif()
        # if(SZIP_LIBRARY_RELEASE)
        set_target_properties(
          SZIP::SZIP PROPERTIES IMPORTED_LOCATION ${SZIP_LIBRARIES}
                                LINK_LIBRARIES ${SZIP_LIBRARIES})
        # endif() if(SZIP_LIBRARY_DEBUG) # libsz_d libszip_d
        # set_target_properties(SZIP::SZIP PROPERTIES IMPORTED_LOCATION_DEBUG
        # ${SZIP_LIBRARY_DEBUG}) endif()
        add_dependencies(SZIP::SZIP szip)
      endif()
 
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${SZIP_DIR}/include")
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                         "${SZIP_DIR}/lib")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                         "${SZIP_DIR}/lib")
 
    endif()
  endif()
endif()