xios.cmake

Go to the documentation of this file.

# Copyright (c) 2019 - 2024 David Guibert
# Copyright (c) 2024 Antoine Morvan
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set_property(GLOBAL PROPERTY xios_can_use_system FALSE)
set_property(GLOBAL PROPERTY xios_depends mpi netcdf libxml2)
 
set(xios_cmake_args "" CACHE STRING "Custom CMake arguments for xios")
set(xios_build_args "" CACHE STRING "Custom make_xios arguments for xios")
 
if(xios_enabled)
  include(macros)
  add_library(xios_deps INTERFACE)
  target_link_libraries(xios_deps INTERFACE MPI::MPI_Fortran netcdf::Fortran
                                            LibXml2::LibXml2)
 
  add_library(xios_options INTERFACE)
  target_compile_options(
    xios_options
    INTERFACE $<$<STREQUAL:"${CMAKE_Fortran_COMPILER_ID}","GNU">:-g
              -fdefault-real-8
              -O3
              -funroll-all-loops
              -fcray-pointer
              -ffree-line-length-none>
              $<$<STREQUAL:"${CMAKE_Fortran_COMPILER_ID}","Intel">:-g
              -xHost
              -align
              array64byte
              -traceback
              -i4
              -r8
              -O3
              -fp-model
              precise
              -fno-alias
              -diag-disable
              1125
              -diag-disable
              279
              -DBOOST_NO_CXX11_DEFAULTED_FUNCTIONS
              -D
              BOOST_NO_CXX11_DELETED_FUNCTIONS>)
 
  add_link_lib(xios_deps)
  message(STATUS "xios link_libs: ${link_libs}")
  add_inc_dirs(xios_deps)
  message(STATUS "xios inc_dirs: ${inc_dirs}")
 
  set(xios_ep)
  if(NOT USE_SYSTEM_libxml2)
    list(APPEND xios_ep libxml2)
  endif()
 
  ExternalProject_Data_Add(
    xios
    ${xios_revision}
    DEPENDS xios_options xios_deps ${xios_ep}
    CONFIGURE_COMMAND
      ${CMAKE_COMMAND} ${cmake_params}
      -DSOURCE_DIR=${PROJECT_SOURCE_DIR}
      -DBINARY_DIR=${PROJECT_BINARY_DIR}
      -DCMAKE_MAKE_PROGRAM=${CMAKE_MAKE_PROGRAM}
      -DXIOS_COMPILE_OPTIONS=$<TARGET_PROPERTY:xios_options,INTERFACE_COMPILE_OPTIONS>
      -DXIOS_USER_INC=${inc_dirs} -DXIOS_USER_LIB=${link_libs} -P
      ${CMAKE_SOURCE_DIR}/projects/xios-configure-files.cmake
      ${default_cmake_args}
      ${xios_cmake_args}
    COMMAND ${CMAKE_COMMAND} -E copy_directory <SOURCE_DIR>/ <BINARY_DIR>/
    COMMAND
      ${CMAKE_COMMAND} -E copy_if_different
      ${CMAKE_BINARY_DIR}/projects/xios-arch-X86_hpcw.fcm
      <BINARY_DIR>/arch/arch-X64_hpcw.fcm
    COMMAND
      ${CMAKE_COMMAND} -E copy_if_different
      ${CMAKE_BINARY_DIR}/projects/xios-arch-X86_hpcw.path
      <BINARY_DIR>/arch/arch-X64_hpcw.path
    COMMAND ${CMAKE_SOURCE_DIR}/bin/patchShebangs <BINARY_DIR> || true
    COMMAND ${CMAKE_SOURCE_DIR}/bin/patchShebangs <SOURCE_DIR> || true
    BUILD_COMMAND ./make_xios --prod --arch X64_hpcw --job
                  ${XIOS_BUILD_PARALLEL_LEVEL} ${xios_build_args}
    INSTALL_COMMAND "")
 
  ExternalProject_Get_Property(xios BINARY_DIR)
  set(XIOS_DIR ${BINARY_DIR})
  message(STATUS "XIOS_DIR: ${XIOS_DIR}")
  set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${XIOS_DIR}/include")
  set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${XIOS_DIR}/lib")
  set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                     "${XIOS_DIR}/lib")
  set_if_not_present(ENV{PATH} "$ENV{PATH}" "${XIOS_DIR}/bin")
 
  add_library(XIOS::Fortran INTERFACE IMPORTED)
  set_property(TARGET XIOS::Fortran PROPERTY INTERFACE_LINK_LIBRARIES
                                             ${XIOS_DIR}/lib/libxios.a)
  set_property(TARGET XIOS::Fortran PROPERTY INTERFACE_INCLUDE_DIRECTORIES
                                             "${XIOS_DIR}/inc")
  add_dependencies(XIOS::Fortran xios)
 
endif()