zlib.cmake

Go to the documentation of this file.

# Copyright (c) 2019 - 2024 David Guibert
# Copyright (c) 2024 Antoine Morvan
# All rights reserved.
#
# SPDX-License-Identifier: Apache-2.0
 
set_property(GLOBAL PROPERTY zlib_can_use_system TRUE)
 
set(zlib_configure_args "" CACHE STRING "Custom configure arguments for zlib")
set(zlib_build_args "" CACHE STRING "Custom Make arguments for zlib")
 
if(zlib_enabled)
  if(USE_SYSTEM_zlib)
    message(STATUS "ZLIB: enabled (system installed)")
    set(FIND_ZLIB_DEBUG ON)
    find_package(ZLIB REQUIRED)
 
    set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${ZLIB_INCLUDE_DIR}")
 
    get_filename_component(ZLIB_DIR "${ZLIB_LIBRARIES}" PATH)
    get_filename_component(ZLIB_DIR "${ZLIB_DIR}" PATH)
    set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}" "${ZLIB_DIR}/lib")
    set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                       "${ZLIB_DIR}/lib")
  else()
    if(NOT TARGET zlib)
      message(STATUS "ZLIB: enabled (internally built)")
 
      ExternalProject_Data_Add(
        zlib
        ${zlib_revision}
        CONFIGURE_COMMAND
        env
          CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
          LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
          CC=${CMAKE_C_COMPILER} CXX=${CMAKE_CXX_COMPILER}
          FC=${CMAKE_Fortran_COMPILER} CFLAGS=-fPIC
          "CFLAGS=-fPIC $ENV{CFLAGS}" "FCFLAGS=-fPIC $ENV{FCFLAGS}"
          "LDFLAGS=$ENV{LDFLAGS}" ./configure
          --prefix=<INSTALL_DIR> ${zlib_configure_args}
        BUILD_COMMAND env
          CPATH=$ENV{CPATH} C_INCLUDE_PATH=$ENV{C_INCLUDE_PATH}
          LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} LIBRARY_PATH=$ENV{LIBRARY_PATH}
          ${CMAKE_MAKE_PROGRAM} -j${BUILD_PARALLEL_LEVEL} ${default_build_args} ${zlib_build_args})
 
      ExternalProject_Get_Property(zlib INSTALL_DIR)
      set(ZLIB_DIR ${INSTALL_DIR})
 
      set(ZLIB_LIBRARIES ${ZLIB_DIR}/lib/libz.so)
      set(ZLIB_INCLUDE_DIRS ${ZLIB_DIR}/include)
      if(NOT TARGET ZLIB::ZLIB)
        add_library(ZLIB::ZLIB UNKNOWN IMPORTED)
        set_target_properties(
          ZLIB::ZLIB PROPERTIES INTERFACE_INCLUDE_DIRECTORIES
                                ${ZLIB_INCLUDE_DIRS})
        if(ZLIB_VERSION)
          set_target_properties(ZLIB::ZLIB PROPERTIES VERSION "${ZLIB_VERSION}")
        endif()
        # if(ZLIB_LIBRARY_RELEASE)
        set_target_properties(
          ZLIB::ZLIB PROPERTIES IMPORTED_LOCATION ${ZLIB_LIBRARIES}
                                LINK_LIBRARIES ${ZLIB_LIBRARIES})
        # endif() if(ZLIB_LIBRARY_DEBUG) # libsz_d libszip_d
        # set_target_properties(ZLIB::ZLIB PROPERTIES IMPORTED_LOCATION_DEBUG
        # ${ZLIB_LIBRARY_DEBUG}) endif()
        add_dependencies(ZLIB::ZLIB zlib)
      endif()
 
      set_if_not_present(ENV{CPATH} "$ENV{CPATH}" "${ZLIB_DIR}/include")
      set_if_not_present(ENV{LIBRARY_PATH} "$ENV{LIBRARY_PATH}"
                         "${ZLIB_DIR}/lib")
      set_if_not_present(ENV{LD_LIBRARY_PATH} "$ENV{LD_LIBRARY_PATH}"
                         "${ZLIB_DIR}/lib")
 
    endif()
  endif()
endif()